Une fois la structure d'une protéine calculée par modélisation moléculaire sous contraintes RMN, la nature de son repliement peut être caractérisée à l'aide du serveur Dali qui recherche les homologues structuraux dans la Protein Data Bank. La macro superpo_complexe.pml est un exemple de script qui permet de superposer une structure de protéine avec une structure homologue en complexe avec un fragment d'ADN en tenant compte de l'analyse Dali.
Pour utiliser cette macro,
la procédure est la suivante :
1) Télécharger
puis modifier le script selon ses besoins
2) Ouvrir PyMOL et charger la macro : File/Open...
Sous Windows, double cliquer directement sur le fichier
################ FICHIER MACRO PYMOL
SUPERPO_COMPLEXE.PML #################
#
# ==> Superposition d'une structure RMN avec une structure homologue de
# proteine en complexe avec un fragment d'ADN.
#
# Pour ignorer une commande, utiliser le sigle "#" en debut de ligne
# qui permet d'indiquer une ligne de commentaire.
#
#
###########################################################################
#
#
# Chargement de la structure PDB KIN17 (resolue par RMN) :
load 2V1N.pdb
select KIN17, (2V1N and (chain A))
#
#
# Chargement de la structure homologue a KIN17 d'apres l'analyse DALI :
# (Il s'agit d'un homodimere en complexe avec un fragment d'ADN.
# Dans cette structure RX, chaine A = B = proteine mecI et
# chaine C = D =double brin d'ADN).
load 1SAX.pdb
select complexe, 1SAX
select chA, (complexe and (chain A))
select chB, (complexe and (chain B))
select DNA, (complexe and (chain C) or (chain D))
color hotpink, chA
color yellow, KIN17
#
#
# Definition des parametres de trace du mode cartoon :
set cartoon_smooth_loops = 0
set cartoon_rect_width = 0.1
set cartoon_rect_length = 1
set cartoon_oval_width = 0.1
set cartoon_oval_length = 1
#
#
# Affichage du fond d'ecran en noir :
bg_color black
#
#
# Cacher les lines, les atomes non lies et afficher le cartoon :
hide nonbonded
hide lines
show cartoon
#
#
# Definition des regions de residus a fitter d'apres l'analyse DALI :
# (le nombre de residus a fitter doit coincider entre les 2 structures)
select Kin_fit, (KIN17 and (i. 21-34 or i. 38-52 or i. 54-60 or i. 70-95 or
i. 96-99))
select mecI_fit, (chA and (i. 9-22 or i. 23-37 or i. 38-44 or i. 49-74 or i.
76-79))
#
#
# Superposition des 2 structures sur les CA et sur les regions selectionnees,
# et calcul du RMSD (la valeur apparait dans la fenetre de dialogue) :
pair_fit (mecI_fit and name ca), (Kin_fit and name ca)
#
#
# Report des coordonnees de la vue selectionnee a l'ecran :
# (pour l'obtenir : bouton "Get View" de la fenetre de dialogue)
set_view (\
0.253670305, -0.332788020, -0.908243179,\
-0.001569805, 0.938810885, -0.344427645,\
0.967289090, 0.088797018, 0.237626180,\
0.000006535, -0.000001945, -118.937370300,\
3.140719414, 0.398800313, -7.326659679,\
-100.058769226, 438.560913086, 0.000000000 )
#
#
# Cacher la chaine B du complexe :
hide cartoon, chB
#
#
###########################################################################
# Tutorial PyMOL de Ludovic Carlier (2006)
# http://www.ludoviccarlier.com
#
#
# PyMOL, programme écrit par DeLano W. L. (2002)
# http://pymol.sourceforge.net/
###########################################################################